I added work around for tcsh

[niv280]

Hi,
i work with tcsh shell and I love zoxide, so I did small work around to adapt zoxide on tcsh.
This is not perfect since tcsh don't got function and it is hard to do add all the if/else of the function from bash to aliases.

zoxide.tcsh.gz

# =============================================================================
# Hook to add new entries to the database.
alias __zoxide_hook 'set __zoxide_pwd_tmp=`pwd`;`if ( ! $?__zoxide_pwd_old )  echo "echo"`>&/dev/null && set __zoxide_pwd_old = "${__zoxide_pwd_tmp}" || `if ( "${__zoxide_pwd_old}" != "${__zoxide_pwd_tmp}" ) echo "echo"`>&/dev/null && set __zoxide_pwd_old = "${__zoxide_pwd_tmp}" && zoxide add -- "${__zoxide_pwd_old}"'
# need to add __zoxide_hook into precmd alias
# ex: alias precmd '__zoxide_hook;set prompt = <your prompt>'
# =============================================================================
# When using zoxide with --no-aliases, alias these internal functions as
# desired.
# Jump to a directory using only keywords.
alias __zoxide_z 'set args_=(\!*);`if ( -d $args_[1] ) echo "echo"`>&/dev/null && cd $args_[1] || set __zoxide_results = `zoxide query -- $args_` && cd ${__zoxide_results}'
alias __zoxide_zi 'set __zoxide_result = `zoxide query -i -- \!*`; __zoxide_cd $__zoxide_result '
unset -f z
unset -v z
alias z '__zoxide_z \!*'
unset -f zi
unset -v zi
alias zi '__zoxide_zi \!*'

the steps you need to do for make this work:

• source zoxide.tcsh
• add __zoxide_hook to the precmd alias. ex: alias precmd '__zoxide_hook;set prompt = <your prompt>'

Now you can use z to navigate easily, the only thing that i didn't able to add is that z alias could not work without argument like in bash, and to return to the previous path ( with z -), since it is really hard to add if condition into aliases.
If someone got better suggestion for tcsh i will love to hear.

Thanks.

[ajeetdsouza]

Thanks @niv280, this is great!

[dertuxmalwieder]

Hmm.

: Command not found.
: Command not found.
: Command not found.
__zoxide_pwd: Command not found.
set: No match.

My .cshrc contains these lines now:

if (`where zoxide` != "") then
  source $HOME/zoxide.tcsh
  alias precmd '__zoxide_hook;set prompt = [%n@%m:%~]%# '
else
  set prompt = '[%n@%m:%~]%# '
endif

[dertuxmalwieder]

I will be outside after 4 PM (CEST), so I guess I won't be able to test the newer version before the weekend. Thank you for your efforts though, I will keep this tab opened.

[niv280]

I edit my first comment with update file.
i hope that solve the

: Command not found.

issue, because i don't sure it's related.
Please let me know.

[ajeetdsouza]

I was getting the : Command not found. issue as well, I was able to fix it by removing all empty lines in the script.

[niv280]

csh is so weird...
Thanks, i will add it above.

[dertuxmalwieder]

I still get:
set: No match.

edit: My fault - I had an error in my prompt. :-)

[dertuxmalwieder]

Hmm...

% ls | grep dot
drwxr-xr-x   8 tux0r  staff   256B  4 Jun 13:24 dotfiles
-rw-r--r--   1 tux0r  staff   384K  4 Jun 13:24 dotfiles.fossil

Yet:

% z dotfiles
zoxide: no match found

[niv280]

I guess this is because of the error you mention above.
can you tell if you get that error when you soyrce the script or when you set the precmd command?

[dertuxmalwieder]

The error is gone, it was my fault.

[zhuzhzh]

I use zi (with fzf), when I select the dir, it will report the error __zoxide_cd: Command not found

to reproduce:

$  zi  <enter>
                    -------------- fzf windows will be opened. select any dir and enter
__zoxide_cd: Command not found

[zhuzhzh]

I add alias __zoxide_cd 'cd \!*', then it works

[adarshdotexe]

Thank you for the great script.

Ended up spending hours trying to get just z and z - as part of the if else alias but ended up having to use a very different technique. The following is part of my .cshrc and it works perfectly

########################################
# Setup ZOXIDE
########################################


# Create a shell script called _z.tcsh
cat > ~/_z.tcsh << "EOF"
#!/bin/tcsh -f
set args = ($*)
set __previous_dir = `test "$args" == "-" && echo 1 || echo 0`
set __dir_exists = `test -d "$args" && echo 1 || echo 0`


if ( $#args == 0 ) then
    cd
else if ( $__previous_dir ) then
    cd -
else if ( $__dir_exists ) then
    cd $args
else
    set __zoxide_result = `zoxide query -- $args`
    cd $__zoxide_result
endif
"EOF"

# Create a shell script called _zi.tcsh
cat > ~/_zi.tcsh << "EOF"
#!/bin/tcsh -f
set __zoxide_result = `zoxide query -i -- $*`
if ( $#__zoxide_result != 0 ) then
    cd $__zoxide_result
endif
"EOF"

# Make the scripts executable
chmod +x ~/_z.tcsh ~/_zi.tcsh

cat > ~/_zoxide_hook.tcsh << "EOF"
#!/bin/tcsh -f
set __zoxide_pwd_tmp = `pwd`
if ( ! $?__zoxide_pwd_old ) then
    set __zoxide_pwd_old = "$__zoxide_pwd_tmp"
else if ( "$__zoxide_pwd_old" != "$__zoxide_pwd_tmp" ) then
    set __zoxide_pwd_old = "$__zoxide_pwd_tmp"
    zoxide add -- "$__zoxide_pwd_old"
endif
"EOF"

alias __zoxide_hook 'source ~/_zoxide_hook.tcsh >& /dev/null'
alias z 'source ~/_z.tcsh'
alias zi 'source ~/_zi.tcsh'

if (`where zoxide` != "") then
  alias precmd '__zoxide_hook;'
endif

[ajeetdsouza]

I've added support for tcsh here: #1047